From comp.graphics.raytracing Fri Aug 12 13:15:26 1994
Path: uniol!zib-berlin.de!zrz.TU-Berlin.DE!netmbx.de!Germany.EU.net!EU.net!howland.reston.ans.net!europa.eng.gtefsd.com!MathWorks.Com!zombie.ncsc.mil!cs.umd.edu!net.usuhs.mil!xserver.oti.disa.mil!dcsc.dla.mil!dsacg3.dsac.dla.mil!nus2571
From: nus2571 (Garrett OBrien)
Newsgroups: comp.graphics.raytracing
Subject: Re: A computer image
Message-ID: <8250@dsacg3.dsac.dla.mil>
Date: 11 Aug 94 16:43:03 GMT
Sender: news@dsacg3.dsac.dla.mil
Organization: dsac-us
Lines: 175
Nntp-Posting-Host: sacuspc151.dsac.dla.mil

alan@command.co.nz (SYSTEM OPERATOR) writes:
>mclark@vt.edu (Michael Clark) writes:
>
>> I have just started playing with GUM and POV2.2 and have discovered that if 
>> you have any artistic talent at all these things work a lot better.
>> 
>> I am trying to create a computer with a picture of a sunrise on the monitor. 
>> I will be using the image as a Windows 3.1 BMP wallpaper for a showcase 
>> of local businesses on Aug 27.  Would anyone like to earn some undying 
>> gratitude/recognition, and possible a few bucks?  (BTW my company's name is 
>> Good Morning Consulting; hence the need/want for a sunrise on a computer 
>> screen.)
>> 
>> Thanks for any help that can be given or comments for how I should start to
>> do this myself.  Michael Clark  (Good.Morning.Consulting@bev.net)
>I too would dearly love a model of a computer, preferably PC.  Has
>anyone with any skill in POV done this?  (I have tried, but the
>result looked more like a spastic microwave!)  If someone has modelled
>a PC, could I have a copy of it please.
>
>Thanks
>Alan 
>
>
>${FLAME} > /dev/null


I had to make a computer a while ago.  It was one of the first things I did,
so it probably is not that great.  It looks ok.  If anyone has some ideas
about making it better, please post or email me.  

Also, is there an ftp site that has stuff like this??   Objects like this would
be nice.  Or, if anyone has an editor that can import stuff like this.
I have seen some editors that will give you the syntax for POV commands, but
it would be nice to have an editor that had library management with it so you
could see what objects you have and a description of them and bring them into
your source.  Just an idea.

-------------------------------------------------------------------------------

with Standard_Disclaimer;
procedure Flames is
   package My_Disclaimer is new Standard_Disclaimer;
begin
   My_Disclaimer.Flames("/dev/null");
end Flames;

---------------------------------- cut here -----------------------------------

// Persistence of Vision Raytracer 2.0
// Computer definition

#include "colors.inc"           // Standard colors library
#include "shapes.inc"           // Commonly used object shapes
#include "textures.inc"         // LOTS of neat textures.  Lots of NEW textures.

#declare KeyColor = pigment {Gray70}
#declare ComputerColor = pigment {Gray90}
#declare LightColor = pigment {Green}

#declare Monitor = union
{
   difference 
   {
      box { <0, 0, 0>, <2, 2, .5> }
      box { <.15, .15, -.1>, <1.85, 1.85, .3> }
   }                              // Box around monitor
   intersection
   {
      sphere { <1, 1, 5> ,5 }
      box { <.15, .15, -.1>, <1.85, 1.85, .3> }
      texture
      {
         pigment {Gray20}      
         finish {phong .6 reflection .3 diffuse .6}
      }
   }                              // Screen
   triangle { <.15, .15, .5>, <1.85, .15, .5>, <1, 1, 2>}
   triangle { <.15, .15, .5>, <.15, 1.85, .5>, <1, 1, 2>}
   triangle { <.15, 1.85, .5>, <1.85, 1.85, .5>, <1, 1, 2>}
   triangle { <1.85, 1.85, .5>, <1.85, .15, .5>, <1, 1, 2>}
                                  // Back tapering off
   box { <.75, .75, 1.5>, <1.25, 1.25, 2> }
                                  // Back Box
   box { <.75, 0, .5>, <1.25, 1.25, 1.5> }
                                  // Stand
   scale <1, .7, 1>
}

#declare CompCase = union
{
   difference
   {
      box { <0, 0, 0>, <2.5, .75, 2.25>}
      box { <1.9, .47, -1e-9>, <2.3, .70, .035>}
                                  // 5 1/4 notch
      box { <1.20, .275, -1e-9>, <1.35, .475, .025>}
                                  // 3 1/2 notch
   }
   disc { <.25, .6, -1e-9>, <0, 0, -1>, .08 pigment {Gray50}}
   disc { <.25, .4, -1e-9>, <0, 0, -1>, .08 pigment {Gray50}}
                                  // Two small buttons
   disc { <1.7, .70, -1e-9>, <0, 0, -1>, .02 pigment {LightColor}}
                                  // 5 1/4 light
   box { <2.075, .50, -.05>, <2.125, .665, 0>}
   cylinder { <2.1, .665, -.05>, <2.1, .665, 0>, .035}
                                  // 5 1/4 knob
   box { <1.5, .60, -1e-9>, <2.4, .65, -1e-9> pigment {Black}}
                                  // 5 1/4 slot
   box { <1.25, .1, -1e-9>, <1.30, .65, 0> pigment {Black}}
                                  // 3 1/2 slot
   box { <1.165, .54, -1e-9>, <1.185, .58, 0> pigment {LightColor}}
                                  // 3 1/2 light
   box { <1.15, .15, -.05>, <1.20, .25, 0>}
                                  // 3 1/2 button
   disc { <2.125, .375, 2.25000001>, z, .275 pigment {Black}} 
                                  // back fan
   box { <.1, .1, 2.25>, <.2, .65, 2.250000001> pigment {Black}}
   box { <.3, .1, 2.25>, <.4, .65, 2.250000001> pigment {Black}}
   box { <.5, .1, 2.25>, <.6, .65, 2.250000001> pigment {Black}}
   box { <.7, .1, 2.25>, <.8, .65, 2.250000001> pigment {Black}}
   box { <.9, .1, 2.25>, <1.0, .65, 2.250000001> pigment {Black}}
   box { <1.1, .1, 2.25>, <1.2, .65, 2.250000001> pigment {Black}}
   box { <1.3, .1, 2.25>, <1.4, .65, 2.250000001> pigment {Black}}
                                  // back slots
   box { <1.6, .1, 2.25>, <1.8, .3, 2.250000001> pigment {Black}}
   box { <1.6, .45, 2.25>, <1.8, .65, 2.250000001> pigment {Black}}
                                  // two misc. boxes in back

}                                  
#declare KeyBoard1 = union
{
   box { <0, 0, 0>, <2.5, .1, 1>}
   box { <.1, .1, .1>, <.2, .15, .6> pigment {KeyColor}}
   box { <.2, .1, .2>, <1.5, .15, .6> pigment {KeyColor}}
   box { <1.5, .1, .1>, <1.6, .15, .6> pigment {KeyColor}}
   box { <.3, .1, .1>, <1.4, .15, .2> pigment {KeyColor}}
   box { <.1, .1, .7>, <.2, .15, .8> pigment {KeyColor}}
   box { <.3, .1, .7>, <.7, .15, .8> pigment {KeyColor}}
   box { <.75, .1, .7>, <1.15, .15, .8> pigment {KeyColor}}
   box { <1.2, .1, .7>, <1.6, .15, .8> pigment {KeyColor}}
   box { <1.65, .1, .7>, <1.95, .15, .8> pigment {KeyColor}}
   box { <1.65, .1, .4>, <1.95, .15, .6> pigment {KeyColor}}
   box { <1.65, .1, .1>, <1.95, .15, .2> pigment {KeyColor}}
   box { <1.75, .1, .2>, <1.85, .15, .3> pigment {KeyColor}}
   box { <2, .1, .1>, <2.4, .15, .6> pigment {KeyColor}}
   box { <2, .1, .7>, <2.4, .1000001, .8> pigment {Gray60}}

   box { <2.09, .1000001, .745>, <2.11, .1000002, .755> pigment {LightColor}} 
   box { <2.19, .1000001, .745>, <2.21, .1000002, .755> pigment {LightColor}} 
   box { <2.29, .1000001, .745>, <2.31, .1000002, .755> pigment {LightColor}} 
   
   rotate <-5, 0, 0>
}

#declare KeyBoard = union
{
   object {KeyBoard1}
   box { <.2, 0, .78>, <2.3, .1, .8>}
}

#declare Computer = union
{
   object {CompCase translate <0, 0, 1.1>}
   object {Monitor translate <.25, .75, 1.2>}
   object {KeyBoard}
   pigment {ComputerColor}
   scale <.95,.95,.95>
}
// end of file



-------------------------------------------------------------------------------
nus2571 sends (Garrett OBrien)...